(Security restrictions of this server do not allow you to retrieve remote RDF data, see details.)

milliseconds (values less than 1000 are ignored)

(The result can only be sent back to browser, not saved on the server, see details)


Examples: ATTED

Example 1

SELECT
    ?gene2 ?mr ?pcc
WHERE {
    # Select genes which co-express with 'geneid:818377'
    <http://atted.jp/rdf/db/Ath.c5-0> atted:gene_pair ?pair .
    ?pair atted:gene_id_1 <http://bio2rdf.org/geneid:818377> .
    ?pair atted:gene_id_2 ?gene2 .
    ?pair atted:mutual_rank ?mr .
    ?pair atted:pcc ?pcc
}
ORDER BY
    ?mr

Example 2

PREFIX uniprot: <http://purl.uniprot.org/core/>

SELECT
    ?geneid2 ?mr ?pcc ?motif

WHERE {
    # selects genes which highly co-express with 'geneid:818614' (ATTED)
    <http://atted.jp/rdf/db/Ath.c5-0> atted:gene_pair ?pair .
    ?pair atted:gene_id_1 <http://bio2rdf.org/geneid:818614> .
    ?pair atted:gene_id_2 ?geneid2 .
    ?pair atted:mutual_rank ?mr .
    ?pair atted:pcc ?pcc

    # converts Bio2RDF's gene URI (http://bio2rdf.org/geneid:...)
    # to UniProt's gene URI (http://purl.uniprot.org/geneid/...) (Bio2RDF)
    SERVICE <http://uniprot.bio2rdf.org/sparql> {
    #SERVICE <http://atted.jp/spatql> {  # please use this SPARQL endpoint if uniprot.bio2rdf.org is down
        ?geneid2 owl:sameAs ?uniprot_gene_uri
    }

    # selects motifs related to `?geneid2` (which highly co-express with 'geneid:818614') (UniProt)
    SERVICE <http://beta.sparql.uniprot.org/sparql> {
        ?protein a uniprot:Protein .

        ?protein rdfs:seeAlso ?uniprot_gene_uri .

        ?protein uniprot:annotation ?annotation .
        ?annotation a uniprot:Motif_Annotation .
        ?annotation rdfs:comment ?motif
    }
}
ORDER BY
    ?mr
LIMIT
    20

Example 3

PREFIX uniprot: <http://purl.uniprot.org/core/>
PREFIX database: <http://purl.uniprot.org/database/>
PREFIX taxonomy: <http://purl.uniprot.org/taxonomy/>

SELECT
    ?protein ?geneid1 ?text ?geneid2
WHERE {

    # selects UniProt entries related to Arabidopsis thaliana with an annotation that contains the word 'photosynthesis'
    SERVICE <http://beta.sparql.uniprot.org/sparql> {
        ?protein a uniprot:Protein .
        ?protein uniprot:organism taxonomy:3702 .
        ?protein uniprot:annotation ?annotation .
        ?annotation a uniprot:Function_Annotation .
        ?annotation rdfs:comment ?text .
        FILTER contains(?text, 'photosynthesis') .

        ?protein rdfs:seeAlso ?uniprot_gene_uri .
        ?uniprot_gene_uri uniprot:database database:GeneID .
    }

    # converts UniProt's gene URI (http://purl.uniprot.org/geneid/...) to
    # Bio2RDF's gene URI (http://bio2rdf.org/geneid:...)
    SERVICE <http://uniprot.bio2rdf.org/sparql> {
    #SERVICE <http://atted.jp/sparql> {  # Please use this endpoint if uniprot.bio2rdf.org is down
        ?geneid1 owl:sameAs ?uniprot_gene_uri
    }

    # selects genes which highly co-express with `?geneid1` (Atted)
    <http://atted.jp/rdf/db/Ath.c5-0> atted:gene_pair ?pair .
    ?pair atted:gene_id_1 ?geneid1 .
    ?pair atted:gene_id_2 ?geneid2 .
}
LIMIT
    10